1     REM *** JUNGLE *** Le Cimetiere des Elephants *** 8/9/83 ***
10    GOTO 1440
20    PRINT "-----------------------------------------------------------":IF C%<1 AND LO%=21 THEN PRINT "Nous sommes dans le noir.":GOTO 90
30    PRINT "Nous sommes ";AL$(LO%);".":S%=1:FOR Y%=1 TO 58:IF D2%(Y%)<>LO% THEN 70
40    S%=S%-1:IF S%=0 THEN PRINT "Nous voyons :":PRINT :LN%=0
41    LN%=LN%+LEN(AC$(Y%))+2
50    IF LN%>60 THEN PRINT ",":LN%=LEN(AC$(Y%)):GOTO 60
51    IF S%<0 THEN PRINT ", ";
60    PRINT AC$(Y%);
70    NEXT:PRINT ".":PRINT :IF LO%=1 THEN PRINT "Directions possibles : SUD":GOTO 90
71    PRINT "Des traces en : ";:RESTORE:FOR Y%=1 TO 6:READ A1$:IF D1%(LO%,Y%)>0 THEN PRINT A1$;" ";
80    NEXT
90    LL%=LO%:PRINT 
92    IF D2%(53)=0 AND LO%=2 THEN 1420:PRINT :PRINT :PRINT A$;"  ";:INPUT A$:PRINT 
100   REM 
110   IF A$="N" THEN A$="ALLER NORD"
111   IF A$="S" THEN A$="ALLER SUD"
112   IF A$="O" THEN A$="ALLER OUEST"
113   IF A$="E" THEN A$="ALLER EST"
114   IF A$="H" THEN A$="ALLER HAUT"
115   IF A$="B" THEN A$="ALLER BAS"
116   IF A$="I" THEN A$="INVE"
120   A$=A$+" ":FOR S%=0 TO LEN(A$)-1:IF MID$(A$,S%,1)<>" " THEN NEXT
130   AV$=LEFT$(LEFT$(A$,S%)+"   ",4):FOR Y%=S% TO LEN(A$)-1:IF MID$(A$,Y%,1)=" " THEN NEXT
140   AN$=LEFT$(RIGHT$(A$,LEN(A$)-Y%)+"    ",4):RETURN
150   IF C%<=0 THEN 160:C%=C%-1:IF C%<11 AND C%>0 THEN PRINT C%;" TOURS AVANT QUE LA TORCHE S'ETEIGNE.":GOTO 160
151   IF C%=0 THEN PRINT "LA TORCHE S'EST ETEINTE !":IF D2%(44)=0 THEN I%=I%-1
152   D2%(44)=23
160   IF LO%<>7 OR D2%(33)<>7 THEN 170:IF D2%(48)=0 THEN PRINT "Des PIGMES semblent nerveux.":GOTO 170
161   IF D2%(48)<>7 THEN 170
162   PRINT "Les PIGMES s'enfuient de frayeur quand le crane sacre tombe":PRINT "au sol!":D2%(33)=23:D2%(34)=7
170   IF D2%(53)<>0 THEN 180
171   IF LL%=16 AND LO%=15 THEN LO%=16:GOTO 1270
172   IF LL%=15 AND LO%=16 THEN LO%=15:GOTO 1270
173   IF LL%=14 AND LO%=3 THEN LO%=14:GOTO 116
180   IF (LL%=3 AND LO%=14) OR (LL%=14 AND LO%=3) THEN PRINT "Nous nous pressons dans un passage etroit!":GOTO 190
181   IF LO%=4 AND C%>0 THEN 840
190   IF LL%=17 AND D2%(38)=17 THEN PRINT "Les lions attaquent !  ";:GOTO 1210
200   IF LL%=6 AND D2%(42)=6 THEN PRINT "Le crocodile attaque !  ";:GOTO 1210
210   IF LL%=8 AND LO%<>8 AND D2%(40)<24 THEN PRINT "Un boa constrictor tombe d'un arbre!  ";:GOTO 1210
220   IF LO%<>12 OR H%<>0 THEN 230
221   PRINT "Un vieux sorcier nous a vu."
222   PRINT "Il hurle quelque chose sur les serpents"
223   PRINT " puis disparait,laissant tomber quelque chose.":H%=1
230   IF LL%=21 AND LL%<>LO% AND D2%(44)>0 AND D2%(44)<>21 THEN PRINT "Nous tombons dans le noir.  ";:GOTO 1210
240   W%=W%-1:IF W%>1 THEN 250:IF -10=W% THEN PRINT "Nous sommes morts de soif.":GOTO 790
241   IF -4>W% THEN PRINT "Nous mourront de soif dans ";10+W%;" tours."
242   IF W%=0 THEN PRINT "Nous n'avons plus d'eau.":D1%(0,0)=0
250   SN%=SN%-1:IF LO%=12 AND SN%<0 THEN SN%=9999
260   IF SN%<=0 THEN 280:IF SN%<9997 THEN D2%(37)=12
261   IF SN%<9993 THEN D2%(37)=11
270   IF SN%<=0 THEN 280:IF LL%=10 AND LO%=11 AND SN%<9991 THEN SN%=9991:GOTO 280
271   IF (LO%=12 AND SN%<9994) OR (LO%=11 AND SN%<9991) THEN PRINT "Des serpents nous mordent !  ";:GOTO 1210
280   A$="Que voulez vous que je fasse ,Bwana":GOSUB 20:IF AV$="SUIV" AND AN$="CART" AND LO%=3 AND D2%(51)=0 THEN IF D2%(53)<=0 THEN 1160:LO%=14:GOTO 150
290   IF AV$="QUIT" THEN 790:FOR V%=1 TO 28:IF AV$<>AV$(V%) THEN NEXT:GOTO 1180
291   IF V%>2 AND AN$=SPC(4) THEN PRINT "Soyez plus precis,svp.":GOTO 150
300   ON V% GOTO 460,1100,800,850,850,920,940,520,390,390,520,310,310,310,750,950,970,920,980,1000,640,730,1010,1060,1350,1350,780,980
310   IF LO%=7 AND AN$="SUD " AND D2%(33)=7 THEN PRINT "Des PIGMES ne veulent pas nous laisser passer.":GOTO 150
320   RESTORE:FOR X%=1 TO 6:READ A$:IF AN$=LEFT$(A$+SPC(4),4) AND D1%(LO%,X%)>0 THEN LO%=D1%(LO%,X%):GOTO 340
330   NEXT:FOR X%=0 TO 12:IF AN$=NC$(X%) AND D2%(X%)=LO% THEN LO%=D3%(X%):GOTO 340
331   NEXT:GOTO 1300
340   IF ((LL%=3 AND LO%=13) OR (LL%=13 AND LO%=3) OR (LL%=19 AND LO%=18) OR (LL%=18 AND LO%=19) OR (LL%=18 AND LO%=15) OR (LL%=15 AND LO%=18)) THEN 341:GOTO 350
341   IF T%=0 THEN LO%=LL%:GOTO 1290
342   IF D2%(53)=0 AND LL%=19 AND LO%=18 THEN LO%=LL%:PRINT "Nous tombons !   ";:GOTO 1270
350   IF (LL%<>22 OR LO%<>19) AND (LL%<>19 OR LO%<>22) THEN 150:IF D2%(44)=0 THEN D2%(44)=23:D2%(57)=0:C%=-C%
360   IF D2%(46)=0 THEN D2%(46)=23:D2%(47)=0
370   IF D2%(56)=0 THEN D2%(56)=23:D2%(57)=0
380   GOTO 150
390   IF I%>4 THEN 1230:FOR X%=43 TO 58
391   IF AN$<>NC$(X%) THEN 400:IF D2%(X%)=0 THEN PRINT "Nous l'avons deja !":GOTO 150
392   IF D2%(X%)=LO% OR (D2%(X%)=50 AND D2%(43)=0) THEN 440
400   NEXT:IF AN$="EAU " THEN IF LO%<>6 AND LO%<>2 AND LO%<>15 AND LO%<>16 AND LO%<>19 AND LO%<>22 THEN 1150:IF D2%(43)>0 THEN 1290:PRINT "Dites moi comment.":GOTO 150
410   IF AN$="HERB" AND LO%=4 THEN X%=46:GOTO 450
411   IF AN$="PIER" AND LO%=10 THEN X%=50:GOTO 450
412   IF AN$="CRAN" AND LO%=5 THEN X%=48:GOTO 450
413   IF AN$="PERC" AND LO%=5 AND D2%(35)=5 THEN X%=49:D2%(35)=23:D2%(36)=5:GOTO 450
420   IF AN$="LIAN" AND LO%=17 THEN IF D2%(55)<>0 THEN 1290:X%=52:GOTO 450
421   IF AN$="IVOI" AND LO%=20 THEN X%=53:GOTO 450
430   FOR X%=1 TO 42:IF AN$=NC$(X%) AND D2%(X%)=LO% THEN 1300:NEXT:GOTO 1150
440   IF D2%(X%)=50 THEN D1%(0,0)=0:GOTO 450
441   IF X%=43 AND W1%>0 THEN W%=W1%:GOTO 450
442   IF X%=58 THEN D2%(58)=23:X%=53
450   D2%(X%)=0:I%=I%+1:PRINT "Voila,c'est fait.":GOTO 150
460   SE%=0:PRINT "Nous transportons :":FOR X%=43 TO 58:IF D2%(X%)<>0 THEN 500:PRINT AC$(X%);:SE%=SE%-1
470   IF X%=54 AND T%=1 THEN PRINT "que vous portez";
480   IF X%<>43 OR D1%(0,0)<=0 THEN 490:PRINT "qui contient ";:IF D1%(0,0)=99 THEN PRINT "de l'eau";:GOTO 490
481   PRINT AC$(D1%(0,0));
490   PRINT 
500   NEXT:IF SE%=0 THEN PRINT "rien du tout !"
510   GOTO 150
520   FOR X%=43 TO 58:IF AN$=NC$(X%) AND D2%(X%)=0 THEN 530:NEXT:GOTO 1190
530   IF AV$<>"METT" THEN 580:A$="Dites moi ou ,en deux mots.":GOSUB 20:A$=AV$+AN$
540   IF A$<>"DANSSAC " THEN 550:IF D2%(43)>0 THEN 1190
541   IF X%=43 OR X%=49 OR X%=53 THEN 1300
542   IF X%=44 THEN AN$="SAC ":GOTO 860
543   IF D1%(0,0)>0 THEN PRINT "Il est plein.":GOTO 150
544   I%=I%-1:D2%(X%)=50:D1%(0,0)=X%:GOTO 1310
550   IF X%<>43 THEN 560:IF D1%(0,0)>0 AND D1%(0,0)<99 THEN PRINT "Vide,pour l'instant.":GOTO 150
551   IF A$="DANSTROU" AND LO%=2 THEN 630
552   IF A$<>"DANS EAU" THEN 560
553   IF LO%=15 OR LO%=16 OR LO%=19 OR LO%=2 OR LO%=22 THEN 630
554   IF LO%=6 THEN PRINT "Non,c'est du poison!":GOTO 150
560   IF X%=53 AND A$="SUR RADE" THEN D2%(53)=23:X%=58:GOTO 620
570   IF X%=54 AND A$="A   PIED" THEN T%=1:GOTO 1310
580   IF LO%<>6 THEN PRINT "Il tombe a terre."
590   IF (X%=46 AND LO%=4) OR (X%=48 AND LO%=5) OR (X%=50 AND LO%=10) THEN D2%(X%)=23:I%=I%-1:GOTO 150
591   IF X%=43 AND W%>0 THEN W1%=W%:W%=0
600   IF X%=54 THEN T%=0
610   IF LO%=6 THEN PRINT "Il coule dans le marais.":D2%(X%)=24:I%=I%-1:GOTO 150
611   IF LO%=9 THEN D2%(X%)=8:I%=I%-1:GOTO 150
620   D2%(X%)=LO%:I%=I%-1:GOTO 150
630   D1%(0,0)=99:W%=25:PRINT "SAC rempli d'eau.":GOTO 150
640   FOR X%=43 TO 58:IF AN$=NC$(X%) AND (D2%(X%)=0 OR D2%(X%)=LO%) THEN 650:NEXT:GOTO 680
650   IF X%<>43 THEN 660:IF D1%(0,0)=0 THEN 1320
651   PRINT "Il contient";:IF D1%(0,0)<59 THEN PRINT " ";AC$(D1%(0,0));".":GOTO 150
652   PRINT "De l'eau pour ";W%;" tours.":GOTO 150
660   IF X%<>45 THEN 670:IF B%=0 THEN 1320:PRINT "Il contient ";B%;" balles.":GOTO 150
670   IF X%=46 OR X%=56 THEN PRINT "C'est sec !":GOTO 150
671   IF X%=47 OR X%=57 THEN PRINT "C'est humide.":GOTO 150
672   IF X%=50 THEN 1340:IF X%=51 THEN 1330
680   IF AN$="TROU" AND LO%=2 THEN PRINT "Il contient de l'eau clair.":GOTO 150
690   IF AN$="ARBR" AND LO%=8 AND D2%(40)=23 THEN D2%(40)=8
700   IF AN$="NOTI" AND LO%=2 THEN 1330:IF AN$="ARBR" AND LO%=8 THEN PRINT "L'ecorce a ete mangee aussi.":GOTO 150
710   IF AN$="PIER" AND LO%=10 THEN 1340
720   IF AN$="BOA " AND LO%=8 AND D2%(40)=8 THEN PRINT "Il est pret a nous fondre dessus !":GOTO 150
721   PRINT "Je ne vois rien de special.":GOTO 150
730   IF AN$<>"NOTI" OR LO%<>2 THEN 740
731   PRINT "Elle dit:":PRINT :PRINT "     GRAND CONCOURS D'EXPLORATEURS AFRICAIN":PRINT :PRINT 
732   PRINT " Le premier concurrent a trouver le legendaire"
733   PRINT " Cimetiere des Elephants et qui ramenera de l'ivoire"
734   PRINT " comme preuve gagnera le concours et recevra un contrat"
735   PRINT " pour d'autres explorations.":GOTO 150
740   IF AN$<>"CART" THEN 1300:IF D2%(51)>0 THEN 1190:PRINT "Il y a un passage a travers la montagne.":GOTO 150
750   IF AN$<>"EAU " AND AN$<>"SAC " THEN 1180
760   IF AN$="SAC " THEN IF D2%(43)>0 THEN 1190:IF W%<1 THEN 1320:GOTO 1260
770   IF W%>=1 THEN 1260
771   IF LO%=2 OR LO%=15 OR LO%=16 OR LO%=19 OR LO%=22 THEN W%=0:GOTO 1260
772   IF LO%=6 THEN PRINT "C'est du poison! Nous sommes morts!":GOTO 790
773   PRINT "Il n'y a rien a boire!":GOTO 150
780   IF AN$<>"EAU " THEN 1180:IF D2%(43)>0 OR W%<1 THEN PRINT "Nous n'en avons pas.":GOTO 150
781   PRINT "L'eau s'ecoule et s'infiltre en terre.":D1%(0,0)=0:W%=0:GOTO 150
790   INPUT "Voulez vous recommencer cette aventure ";A$:PRINT :IF LEFT$(A$,1)="O" THEN 1440:END
800   IF AN$<>"SILE" AND AN$<>"PIER" THEN PRINT "Nous pouvons seulement prendre du silex.":GOTO 150
801   IF D2%(50)>0 THEN 1190:IF LO%=4 THEN 840
810   PRINT "Du silex jaillit une petite etincelle.":IF D2%(46)=0 THEN PRINT "L'herbe s'enflamme et brule.":D2%(46)=23:I%=I%-1
820   IF D2%(52)=0 THEN PRINT "Les lianes s'enflamment et brulent.":D2%(52)=23:I%=I%-1
830   IF D2%(56)=0 THEN PRINT "La torche prend feu.":D2%(56)=23:D2%(44)=0:C%=-C%
840   IF LO%=4 THEN PRINT "Des flammes !.La brousse est en feu !  ";:GOTO 1210
850   IF D2%(50)>0 AND D2%(44)>0 THEN PRINT "Il nous faut une flamme ou du silex.":GOTO 150
851   IF LO%=4 THEN 840
860   IF AN$<>"SAC " THEN 890:IF D2%(43)>0 THEN 1190
861   PRINT "Le sac fond";:D2%(43)=23:I%=I%-1:IF W%>0 THEN PRINT " et l'eau disparait en terre";:W%=0:GOTO 880
870   IF D1%(0,0)<=0 THEN 880:PRINT "et le contenu (";AC$(D1%(0,0));")"
871   IF D1%(0,0)=46 OR D1%(0,0)=51 OR D1%(0,0)=52 THEN PRINT "brule aussi";:D2%(D1%(0,0))=23:GOTO 880
872   PRINT "tombe au sol";:D2%(D1%(0,0))=LO%
880   PRINT ".":GOTO 150
890   FOR X%=44 TO 58:IF AN$=NC$(X%) AND D2%(X%)=0 THEN 900:NEXT
891   FOR X%=1 TO 42:IF AN$<>NC$(X%) THEN NEXT:GOTO 1190
892   IF D2%(X%)=LO% THEN 910:GOTO 1150
900   IF X%=46 OR X%=49 OR X%=51 OR X%=52 THEN D2%(X%)=23:I%=I%-1:PRINT "ca brule.":GOTO 150
901   IF X%=56 THEN 830:IF X%=44 THEN PRINT "Deja brule!":GOTO 150
902   GOTO 1170
910   IF X%=13 OR X%=9 OR X%=19 OR X%=22 OR X%=25 OR X%=29 OR X%=30 OR X%=35 OR X%=36 OR X%=41 THEN 1170:GOTO 1300
920   IF AN$<>"TORC" THEN 930:IF D2%(52)=0 AND D2%(46)=0 THEN D2%(46)=23:D2%(52)=23:D2%(56)=0:I%=I%-1:C%=-20:GOTO 1310
921   IF D2%(47)=0 THEN PRINT "Pas avec de l'herbe humide.":GOTO 150
922   GOTO 1290
930   IF AN$<>"RADE" THEN 1180
931   IF D2%(52)<>0 OR D2%(49)<>0 THEN 1290
932   IF LO%=16 OR LO%=15 THEN D2%(52)=23:D2%(49)=24:I%=I%-2:D2%(39)=LO%:GOTO 1310
933   PRINT "Pas ici.":GOTO 150
940   IF AN$<>"BOTT" OR D2%(54)<>0 THEN 1300:T%=1:GOTO 1310
950   FOR X%=43 TO 58:IF AN$=NC$(X%) AND D2%(X%)=0 THEN 960:NEXT:GOTO 130
960   IF X%<>55 THEN 580:IF LO%=8 AND D2%(41)>8 THEN D2%(55)=8:I%=I%-1:GOTO 1280
961   IF LO%=17 AND D2%(38)=17 THEN PRINT "Ca ne l'arrete pas !":GOTO 150
962   IF LO%=7 AND D2%(33)=7 THEN 1080:GOTO 580
970   IF AN$<>"TORC" THEN 1180:IF D2%(56)=0 OR D2%(57)=0 THEN PRINT "Ce n'est pas eclaire.":GOTO 980
971   IF D2%(44)=0 THEN D2%(44)=23:D2%(56)=0:C%=-C%:GOTO 1310
972   GOTO 1190
980   IF AN$<>"RADE" THEN 1300:IF D2%(39)<>LO% THEN 1150:IF D2%(39)=16 THEN D2%(39)=15:LO%=15:IF D2%(58)<>16 THEN 150:D2%(58)=15:GOTO 150
990   IF D2%(39)=15 THEN D2%(39)=16:LO%=16:IF D2%(58)<>15 THEN 150:D2%(58)=16:GOTO 150
1000  IF LO%=6 THEN 310
1005  IF LO%<>15 THEN 1007
1006  IF AN$<>"RIVE" AND AN$<>"EST " THEN 1300:LO%=16:GOTO 150
1007  IF LO%<>16 THEN 1009
1008  IF AN$<>"RIVE" AND AN$<>"OUES" THEN 1300:LO%=15:GOTO 150
1009  IF (LO%<>19 OR AN$<>"RIVE") AND AN$<>"NORD" THEN 1300:LO%=16:GOTO 150
1010  IF AN$="CROC" AND LO%=6 AND D2%(42)=6 THEN 1016:GOTO 1018
1016  IF D2%(45)=0 THEN 1060:GOSUB 1250:GOTO 150
1017  IF AN$="SERP" AND (LO%=11 OR LO%=12) THEN 1018:GOTO 1020
1018  IF D2%(55)=0 THEN 1220
1019  IF D2%(45)=0 THEN 1060:GOSUB 1250:GOTO 150
1020  IF AN$="BOA " AND LL%=8 THEN 1021:GOTO 1030
1021  IF D2%(55)=0 THEN 1280:IF D2%(45)=0 THEN 1060:GOSUB 1250:GOTO 1200
1030  IF AN$="PIGM" AND LO%=7 AND D2%(33)=7 THEN IF D2%(45)=0 THEN 1060:IF D2%(55)=0 THEN 1080:GOSUB 1250:GOTO 150
1040  IF AN$="LION" AND LO%=17 AND D2%(38)=17 THEN 1041:GOTO 1150
1041  IF D2%(45)=0 AND B%>0 THEN 1060:IF D2%(55)=0 THEN PRINT "Il est blesse ,et attaque!   ";:GOTO 1210
1042  GOSUB 1250:GOTO 1200
1060  IF D2%(45)>0 THEN 1300:IF B%=0 THEN PRINT "Plus de balle.  ";:GOTO 1300
1061  B%=B%-1:PRINT "PAN !  ";
1070  IF LO%=6 AND D2%(42)=6 THEN PRINT "Le crocodile est mort et flotte a la surface.":D2%(42)=23:GOTO 150
1071  IF LO%=8 AND D2%(41)>8 THEN 1280:IF LO%=17 AND D2%(38)=17 THEN PRINT "Le lion est serieusement blesse et s'ecroule.":D2%(38)=23:GOTO 150
1080  IF LO%=7 AND D2%(33)=7 THEN PRINT "Nous en avons tue un,mais le reste attaque !   ":GOTO 1210
1081  IF (LO%=11 OR LO%=12) AND D2%(37)=LO% THEN 1220
1090  PRINT "Rate .":GOTO 150
1100  IF LO%=3 AND D2%(51)>0 THEN PRINT "Nous avons besoin d'une carte pour traverser la      montagne.":GOTO 150
1110  IF LO%=7 AND D2%(33)=7 THEN PRINT "Essaie du JU-JU.":GOTO 150
1120  IF LO%=16 AND D2%(53)<23 THEN PRINT "Nous pouvons traverser avec l'ivoire mais pas en la  portant.":GOTO 150
1130  IF LO%=22 AND (D2%(44)<>0 OR D2%(56)<>0 OR D2%(57)<>0) THEN PRINT "Essayez de faire une torche !":GOTO 150
1140  PRINT "Pas maintenant.":GOTO 150
1150  PRINT "Je ne le vois pas ici.":GOTO 150
1160  PRINT "Quelque chose est trop gros!":GOTO 150
1170  PRINT "Ca ne brule pas.":GOTO 150
1180  PRINT "Je ne vous comprend pas tres bien ...":GOTO 150
1190  PRINT "Nous ne l'avons pas.":GOTO 150
1200  PRINT "IL attaque !   ";
1210  PRINT "Nous avons ete tues !":GOTO 790
1220  PRINT "Un de mort,mais le reste vient.":GOTO 150
1230  PRINT "Je ne peux pas.Nous en portons trop!":GOTO 150
1240  PRINT "Je ne sais pas le faire.":GOTO 150
1250  PRINT "Nous n'avons rien pour tuer.":RETURN
1260  PRINT "Slurp !  Ahhh !":GOTO 150
1270  PRINT "Quelque chose est trop lourd !":GOTO 150
1280  D2%(40)=24:D2%(41)=8:PRINT "Le boa est mort!":GOTO 150
1290  PRINT "Nous ne pouvons pas le faire ... pour l'instant !":GOTO 150
1300  PRINT "Nous ne pouvons pas.":GOTO 150
1310  PRINT "O.K.":GOTO 150
1320  PRINT "Vide !":GOTO 150
1330  PRINT "Il y a quelquechose d'ecrit dessus !":GOTO 150
1340  PRINT "Elles sont en silex!":GOTO 150
1350  IF AN$<>"JEU " THEN 1180
1360  IF V%=26 THEN 1380
1370  DIM SAV%(11)
1371  SAV%(0)=FG%:SAV%(1)=LO%:SAV%(2)=LL%:SAV%(3)=B%:SAV%(4)=C%:SAV%(5)=I%:SAV%(6)=W%:SAV%(7)=W1%:SAV%(8)=H%:SAV%(9)=T%
1372  SAV%(10)=SN%:SAV%(11)=D1%(0,0)
1373  INPUT "Sous quel nom :";NOM$:PRINT :CALLM #F000:REM SKIP
1374  SAVEA SAV% NOM$+".ele1":SAVEA D2% NOM$+".ele2":GOTO 150
1380  DIM SAV%(11)
1381  INPUT "Quelle sauvegarde :";NOM$:PRINT 
1382  LOADA SAV% NOM$+".ele1":LOADA D2% NOM$+".ele2"
1383  FG%=SAV%(0):LO%=SAV%(1):LL%=SAV%(2):B%=SAV%(3):C%=SAV%(4):I%=SAV%(5):W%=SAV%(6):W1%=SAV%(7):H%=SAV%(8):T%=SAV%(9)
1384  SN%=SAV%(10):D1%(0,0)=SAV%(11)
1385  GOTO 150
1420  PRINT :PRINT "Nous sommes revenu au bureau de poste avec de l'ivoire "
1421  PRINT "du Cimetiere des Elephants !"
1422  PRINT "Vous avez ete engage pour retrouver les legendaires,"
1423  PRINT "et depuis longtemps perdues,"
1424  PRINT :PRINT TAB(10);"Mines du Roi Salomon":PRINT TAB(10);"--------------------":PRINT :PRINT :PRINT "(constituant la 2eme partie de JUNGLE)"
1425  END
1440  CLEAR 10000:MODE 0:PRINT CHR$(12)
1441  DIM D2%(58),D1%(22,6),AV$(28),AC$(58),NC$(58),AL$(22),D3%(12)
1442  B%=6:W%=0:I%=0:SN%=0:CURSOR 23,15:PRINT "JUNGLE":CURSOR 22,13:PRINT "Aventure"
1450  CURSOR 15,10:PRINT "Le Cimetiere des Elephants":WAIT TIME 100
1451  FOR X%=1 TO 6:READ A$:NEXT:FOR X%=1 TO 22:READ AL$(X%):FOR Y%=1 TO 6:READ D1%(X%,Y%):NEXT:NEXT
1452  FOR X%=1 TO 42:READ AC$(X%),NC$(X%),D2%(X%):IF X%<13 THEN READ D3%(X%)
1460  NEXT:FOR X%=43 TO 58:READ AC$(X%),NC$(X%),D2%(X%):NEXT
1461  FOR X%=1 TO 28:READ AV$(X%):NEXT
1462  NC$(0)="POST":D2%(0)=2:D3%(0)=1:LO%=2:PRINT CHR$(12);"Je suis votre guide africain.":GOTO 150
1470  DATA NORD,SUD,EST,OUEST,HAUT,BAS,a l'interieur d'un bureau de poste desert,0,2,0,0,0,0,a l'exterieur d'un bureau de poste
1471  DATA 0,0,3,4,0,0,au pied d'une montagne,0,0,0,2,13,0,marchant dans la brousse,0,6,2,0,0,0
1472  DATA sur une piste sinueuse,0,7,6,0,0,0,traversant un marais,4,8,0,5,0,0,dans un village Pigme,5,10,8,0,0,0
1473  DATA dans une clairiere,6,0,0,7,0,0,sur un arbre,0,0,0,0,0,8,dans un canyon,7,11,0,0,0,0
1474  DATA pres d'une cite perdue,10,0,12,0,0,0,a l'exterieur d'un ancien temple,0,0,0,11,0,0
1475  DATA au sommet d'une montagne,0,17,0,0,0,3,dans une vallee inconnue,0,0,15,3,0,0
1476  DATA sur le cote ouest de la riviere,0,0,16,14,18,0,sur la rive est de la riviere,0,19,0,15,0,0
1477  DATA dans une jungle dense,13,0,18,0,0,0,au sommet d'une falaise,15,0,19,17,0,0
1478  DATA a la fin sud de la vallee inconnue,16,0,0,0,18,0,dans le Cimetiere des Elephants,0,0,21,0,0,0
1479  DATA dans une caverne faiblement eclairee,0,0,22,20,0,0
1500  DATA devant une chute d'eau,19,0,0,21,0,0,un village indigene au sud,VILL,5,7
1501  DATA un temple a l'est,TEMP,11,12,une riviere a l'est,RIVE,14,15,une falaise au sud,FALA,15,18
1502  DATA "une vallee inconnue loin au dessous,une falaise glissante a l'est",FALA,18,19
1503  DATA une piste escarpee descend la falaise au nord,PIST,18,15,une chute d'eau alimentant la riviere,EAU ,19,22
1504  DATA une sombre grotte a ouest,GROT,22,21,un arbre mort,ARBR,8,9,un passage etroit a l'ouest,PASS,14,3
1505  DATA une piste escarpee escaladant la falaise,PIST,15,18,une falaise glissante,FALA,19,18,des rangees de pierres plates
1506  DATA PIER,1,un trou rempli d'eau,TROU,2,des falaises se dressant devant nous,FALA,3,de l'herbe seche partout,HERB,4
1507  DATA de l'eau croupie tout autour,EAU ,6,une muraille de pierres escarpee,MURA,10,une porte scellee,PORT,12
1508  DATA des rochers loin dessous,ROCH,13,une falaise a pic infranchissable au nord,FALA,16
1509  DATA de la resine s'ecoulant des arbres,RESI,17,beaucoup de squelettes d'elephants,SQUE,20,des murailles humides,MURA,21
1510  DATA une notice recente,NOTI,2,des huttes indigenes a l'ouest,HUTT,9,un marais au nord,MARA,9,des pierres couvrant le sol
1511  DATA PIER,10,les restes d'un ancien safari,REST,14,de l'ivoire en tas,IVOI,20,de l'eau limpide,EAU ,15,de l'eau limpide,EAU 
1512  DATA 16,un groupe de Pigmes,PIGM,7,une clairiere vide,CLAI,23,des cranes suspendus a des perches,CRAN,5,des cranes au sol
1513  DATA CRAN,23,des serpents venimeux allant vers nous,SERP,23,un lion rugissant vous chargant,LION,17
1514  DATA un radeau fait de lianes et de perches,RADE,23,un grand boa constrictor,BOA ,23,un boa mort,BOA ,23
1515  DATA un grand crocodile nageant vers nous,CROC,6
1600  DATA un sac en plastique,SAC ,1,une torche allumee,TORC,23,un revolver,REVO,1,plusieurs poignees d'herbe,HERB,23
1601  DATA de l'herbe humide,HERB,23,un crane,CRAN,23,un tas de perches,PERC,23,plusieurs pierres,PIER,23,une carte,CART,12
1602  DATA des lianes,LIAN,23,de l'ivoire,IVOI,23,des bottes d'escalades,BOTT,14,une machette aiguisee,MACH,8
1603  DATA une torche faite d'herbes et de lianes,TORC,23,une torche humide,TORC,23,de l'ivoire sur le radeau,IVOI,23
1700  DATA INVE,AIDE,FRAP,BRUL,ALLU,FAIR,PORT,METT,OBTI,PREN,DESC,GRIM,ALLE,MARC,BOIR,JETE,ETEI,FABR,MONT,NAGE,REGA
1701  DATA LIRE,TUER,TIRE,SAUV,CHAR,VERS,LANC
*